clear
cap log close
log using confa-sj-order-an, replace


local toapp : dir . files "*.dta"

tokenize `"`toapp'"'
use `1'
mac shift
while "`1'"!="" {
  append using `1'
  mac shift
}

cd ..

lab var time "Elapsed time"
lab var n "Number of observations"
lab var nfac "Number of factors"
lab var nipf "Number of indicators per factor"
lab var init "Type of starting values"
lab def init 1 "Smart" 2 "IV"
lab var init init

g nobsvar = nfac*nipf
lab var nobsvar "Number of observed variables"

g npar = nobsvar*2 + nfac*(nfac+1)/2 - nfac
lab var npar "Number of parameters"

tab converged
foreach x of varlist time n nfac nipf nobsvar npar {
  gen l`x' = ln( `x' )
  lab var l`x' " `: var lab `x' ' "
}

reg ltime ln, robust
* est store n

reg ltime lnobsvar, robust
* est store o

reg ltime ln lnfac, robust
est store n_f

reg ltime ln lnobsvar, robust
est store n_o

reg ltime ln lnfac lnipf, robust
est store n_f_i

reg ltime ln lnfac lnobsvar, robust
est store n_f_o

reg ltime ln lnpar, robust
est store n_p

reg ltime ln lnpar lnfac, robust
est store n_p_f

reg ltime ln lnpar lnobsvar, robust
est store n_p_o

est tab _all, stat(aic bic r2)

estout _all using confa-sj-order.tex, ///
   style(tex) stats( aic bic r2, fmt( %6.2f %6.2f %6.4f ) labels( AIC BIC "$ R^2$" ) ) ///
   label replace c( b( fmt(%5.3f) ) ) mlabel( , none  ) numbers drop( _cons )

exit