*! version 1.0.0 June 28, 2006 @ 10:38:09
*! Sumarize information on (person specific) sequences
program define sqtab, rclass
version 9
	syntax [varname(default=none)] [if] [in] ///
	  [, nosort ranks(numlist) so se gapinclude * ]

	// Sq-Data
	if "`_dta[SQis]'" == "" {
		di as error "data not declared as SQ-data; use -sqset-"
		exit 9
	}

	// if/in
	if "`if'" != "" {
		tokenize "`if'", parse(" =+-*/^~!|&<>(),.")
		while "`1'" != "" {
			capture confirm variable `1'
			if !_rc {
				local iflist  "`iflist' `1'"
			}
			macro shift
		}
	}
	if "`iflist'" != "" CheckConstant `iflist', stop
	marksample touse 

	// Options
	if "`varlist'" == "" local sort = cond("`sort'"=="nosort","","sort")
	else local sort = "" 

	quietly {
		
		preserve

		// Drop Sequences with Gaps 
		if "`gapinclude'" == "" {
			tempvar lcensor rcensor gap
			by `_dta[SQiis]' (`_dta[SQtis]'), sort: gen `lcensor' = sum(!mi(`_dta[SQis]'))
			by `_dta[SQiis]' (`_dta[SQtis]'): gen `rcensor' = sum(mi(`_dta[SQis]'))
			by `_dta[SQiis]' (`_dta[SQtis]'): ///
			  replace `rcensor' = ((_N-_n) == (`rcensor'[_N]-`rcensor'[_n])) & mi(`_dta[SQis]')
			by `_dta[SQiis]' (`_dta[SQtis]'): ///
			gen `gap' = sum(mi(`_dta[SQis]') & `lcensor' & !`rcensor')
			by `_dta[SQiis]' (`_dta[SQtis]'): ///
			replace `touse' = 0 if `gap'[_N]>0
		}
		keep if `touse'
		if _N == 0 {
			noi di as text "(No observations)"
			exit
		}

		if "`so'" == "so" {
			by `_dta[SQiis]' (`_dta[SQtis]'), sort: keep if `_dta[SQis]' ~= `_dta[SQis]'[_n-1]
			by `_dta[SQiis]' (`_dta[SQtis]'): replace `_dta[SQtis]' = _n
		}
		
		if "`se'" == "se" {
			by `_dta[SQiis]' `_dta[SQis]', sort: keep if _n == 1
			by `_dta[SQiis]' (`_dta[SQis]'): replace `_dta[SQtis]' = _n
		}

		// Option ranks
		if "`ranks'" != "" {
			tempfile original frequency
			save `original'
			tempvar n
			keep `_dta[SQiis]' `_dta[SQtis]' `_dta[SQis]' `touse'
			keep if `touse'
			reshape wide `_dta[SQis]', i(`_dta[SQiis]') j(`_dta[SQtis]')
			bysort `_dta[SQis]'*: gen `n' = _N
			bysort `_dta[SQis]'*: keep if _n==1
			keep `_dta[SQiis]' `n'
			KeepRanks `n', ranks(`ranks') 
			sort `_dta[SQiis]'
			save `frequency'
			use `original', clear
			sort `_dta[SQiis]'
			merge `_dta[SQiis]' using `frequency'
			keep if _merge==3
			drop _merge
		}

		// Reshape to Wide
		// ---------------
	
		keep `varlist' `iflist' `_dta[SQiis]' `_dta[SQtis]' `_dta[SQis]' `n' `touse'
		reshape wide `_dta[SQis]', i(`_dta[SQiis]') j(`_dta[SQtis]')
		sort `_dta[SQis]'*

		// Generate Display-Variable
		// -------------------------
		
		tempvar pattern

		// Essential code from egen-concat
		gen str1 `pattern' = "" 
		foreach var of varlist `_dta[SQis]'* {
			capture confirm string variable `var'
			if _rc {
				replace `pattern' = `pattern' + cond(string(`var')=="."," ",string(`var'))
			}
			else {
				replace `pattern' = `pattern' + `var' 
			}
		}
		replace `pattern' = trim(substr(`pattern',1,length(`pattern')))

		// I want labels
		local label = ////
		  cond("`se'"=="" & "`so'"=="","Sequence-Pattern",  ///
		  cond("`se'"=="" & "`so'"!="","Sequence-Order", ///
		  cond("`se'"!="" & "`so'"=="","Sequence-Elements","")))
		label variable `pattern' "`label'"
		  
	}

	// Output
	// ------

	local fweight = cond("`ranks'"=="","","[fweight=`n']")
	tab `pattern' `varlist' `fweight', `sort' `options'

	// Return
	// ------

	return scalar N = r(N)
	return scalar r = r(r)
	if "`varlist'" != "" return scalar c = r(c)
	
	end
		

program CheckConstant, rclass
	syntax varlist(default=none) [, stop]
	sort `_dta[SQiis]'
	foreach var of local varlist {
		capture by `_dta[SQiis]': assert `var' == `var'[_n-1] if _n != 1
		if _rc & "`stop'" == "" {
			di as res "`var'" as text " is not constant over time; not used"
			local varlist: subinstr local varlist "`var'" "", word
		}
		if _rc & "`stop'" != "" {
			di as error "`var' is not constant over time"
			exit 9
		}
		if "`stop'" == "" {
			return local checked "`varlist'"
		}
	}
end


// Selects Ranks according to rank-Options
program KeepRanks
	syntax varname, ranks(string)
	tempvar rank tieshelp tiesrank select
	by `varlist', sort: gen int `rank' = _n==1
	gen int `tieshelp' = _N+1 - _n
	replace `rank' = sum(`rank')
	replace `rank' = `rank'[_N] +1  - `rank'
	sort `tieshelp'
	gen `tiesrank' = `tieshelp' if `rank'!=`rank'[_n-1] & `rank' <= `tieshelp'
	by `rank', sort: replace `rank' = `tiesrank'[1]
	gen int `select' = 0
	foreach r of local ranks {
		replace `select' = 1 if `rank'  == `r'
	}
	keep if `select'
end