* tmap_propsymbol NJC 1.1.0 14 July 2004                                   
*! -tmap_propsymbol-: Proportional symbol maps                                 
*! Version 1.2 - 23 July 2004                                                  
*! Version 1.0 - 24 January 2004                                               
*! Author: Maurizio Pisati                                                     
*! Department of Sociology and Social Research                                 
*! University of Milano Bicocca (Italy)                                        
*! maurizio.pisati@unimib.it                                                   




*  ----------------------------------------------------------------------------
*  1. Define program                                                           
*  ----------------------------------------------------------------------------

program tmap_propsymbol
version 8.2




*  ----------------------------------------------------------------------------
*  2. Define syntax                                                            
*  ----------------------------------------------------------------------------

syntax varname(numeric) [if] [in],   ///
		 Xcoord(varname numeric)       ///
		 Ycoord(varname numeric)       ///
		 Map(string)                   ///
      [SColor(string)]               ///
      [SSIze(real 1)]                ///
      [SSHape(string)]               ///
      [OColor(string)]               ///
      [OSize(string)]                ///
      [FColor(string)]
		



*  ----------------------------------------------------------------------------
*  3. Check syntax                                                             
*  ----------------------------------------------------------------------------

/* Marksample */
marksample touse
markout `touse' `xcoord' `ycoord'
qui count if `touse' 
if r(N) == 0 error 2000 

/* Check option map() */
capture confirm file `"`map'"'
if _rc {
	di as err ///
	"file `map' specified in option {bf:{ul:m}ap()} does not exist"
	exit 498 
} 




*  ----------------------------------------------------------------------------
*  4. Define basic objects                                                     
*  ----------------------------------------------------------------------------

/* Preserve data */
preserve

/* Set default symbol color */
if "`scolor'" == "" local scolor "black"

/* Set symbol size */
su `varlist', meanonly
qui replace `varlist' = ((`varlist' -  r(min)) / r(max)) + (r(max) - r(min))/100

/* Set default symbol shape */
if "`sshape'" == "" local sshape "Oh"

/* Set default outline color */
if "`ocolor'" == "" local ocolor "black"

/* Set default outline thickness */
if "`osize'" == "" local osize "thin"

/* Set default fill color */
if "`fcolor'" == "" local fcolor "white"

/* Keep only relevant cases */
qui keep if `touse' 
	
/* Keep only relevant varlists */
qui keep `varlist' `xcoord' `ycoord'
cap rename `varlist' _attribute
cap rename `xcoord' _x
cap rename `ycoord' _y




*  ----------------------------------------------------------------------------
*  5. Draw map                                                                 
*  ----------------------------------------------------------------------------

/* Calculate plot region */
qui { 
	merge using `"`map'"'
	tempvar ID
	egen `ID'=group(_ID) 
	tab `ID'
	local NPOLY = r(r)
   su _Y, meanonly 
	local ymin = r(min)
	local ymax = r(max)
 	su _X, meanonly 
	local xmin = r(min)
	local xmax = r(max)
	local JY = (`ymax' - `ymin') * 0.03
	local JX = (`xmax' - `xmin') * 0.03
	local ymin = `ymin' - `JY'
  	local ymax = `ymax' + `JY'
	local xmin = `xmin' - `JX'
	local xmax = `xmax' + `JX'
	local RATIO = (`ymax' - `ymin') / (`xmax' - `xmin')
	local YS = 4
	local XS = 4 / `RATIO'
}

/* Draw map */
local GRAPHS 
local OC "`ocolor'"
local OS `osize'
local FC "`fcolor'"
if "`OC'" == "none" local OC "`FC'"
forval i = 1/`NPOLY' {
	local GRAPHS "`GRAPHS'(area _Y _X if `ID'==`i', nodropbase blc("`OC'") blw(`OS') bfc("`FC'")) "
}
local GRAPHS "`GRAPHS'(scatter _y _x [fw=_attribute], ms(`sshape') mc(`scolor') "
local GRAPHS "`GRAPHS'msize(*`ssize')) "

cap graph twoway `GRAPHS', ysize(`YS') xsize(`XS')                       ///
          yscale(r(`ymin' `ymax') off) xscale(r(`xmin' `xmax') off)      ///
          ylabel(`ymin' `ymax') xlabel(`xmin' `xmax')                    ///
          ytitle("") xtitle("")                                          ///
          plotregion(style(none)) scheme(s1mono) legend(off) `options' 

if _rc {
	di as err "{p}invalid syntax{p_end}"
	exit _rc 
}




*  ----------------------------------------------------------------------------
*  6. End program                                                              
*  ----------------------------------------------------------------------------

restore
end