/*
  levpet

*! VERSION 1.0.0  07nov2003

*/

VERSION 8.0

INCLUDE _std_large
INCLUDE _ht310
INCLUDE header
HELP hlp1, view("help levpet")
RESET res1

DIALOG main, label("levpet - Levinsohn-Petrin productivity estimator")	///
		tabtitle("Main")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_panelset
  
  TEXT     tx_depvar   _lft        _topph    _vnwd       .,		///
		label("Dependent variable:")
		
  TEXT     tx_capital  _vlx   	   @         @           .,		///
  		label("Capital variable:")
  
  VARNAME  vn_depvar   _lft        _ss       @           .,		///
		label("Dependent variable")

  VARNAME  vn_capital  _vlx        @         @           .,		///
		label("Capital variable") 				///
		option(capital)
		
  TEXT     tx_free     _lft   	   _ls       _iwd        .,		///
  		label("Freely variable inputs:")
  VARLIST  vl_free     @           _ss       @           .,		///
  		label("Freely variable inputs")				///
  		option(free)
  		
  TEXT     tx_proxy    _lft   	   _ls       _iwd        .,		///
  		label("Proxy variables:")
  VARLIST  vl_proxy    @           _ss       @           .,		///
  		label("Proxy variables")				///
  		option(proxy)  

  GROUPBOX gb_opts     _lft        _ls       _iwd        _ht10,		///
  		label("Options")
  RADIO    rb_value    _ilft       _ss       _cwd2       .,		///
  		label("Value added")					///
  		option(valueadded)					///
  		onclickon(script value_on) first
DEFINE y @y  		
  RADIO    rb_revenue  @           _ss       @           .,		///
  		label("Revenue (GMM)")					///
  		option(revenue)						///
  		onclickon(script revenue_on) last
  CHECKBOX ck_justid   _indent2    _ss       _cwd4       .,		///
  		label("Just identified")				///
  		option(justid)
  CHECKBOX ck_grid     _lft2       @         _cwd2       .,		///
  		label("Grid search")					///
  		option(grid)
  		
  SPINNER  sp_reps     _ilft       +35       _spwd      .,		///
                label("Bootstrap replications")				///
		option(reps)						///
                min(1)							///
                max(100000)						///
                default(50)
  TEXT     tx_reps     _spsep      @         _spr2b     .,		///
                label("Bootstrap replications")  		

  DEFINE _x _lft2
  DEFINE _cx _spr2b
  DEFINE _y @
  INCLUDE _sp_level                
END

SCRIPT value_on
BEGIN
	main.ck_justid.disable
	main.ck_grid.disable
END

SCRIPT revenue_on
BEGIN
	main.ck_justid.enable
	main.ck_grid.enable
END

INCLUDE ifin

PROGRAM command
BEGIN
  put "levpet "
  varlist main.vn_depvar
  require main.vn_capital 
  require main.vl_free
  require main.vl_proxy
  INCLUDE _ifin_pr
  beginoptions
  	optionarg main.vn_capital
  	optionarg main.vl_free
  	optionarg main.vl_proxy
	option main.rb_revenue
	option main.ck_justid
	option main.ck_grid
	optionarg /hidedefault main.sp_reps
	optionarg /hidedefault main.sp_level
  endoptions	
END